Gecko [ www.agenciac4designer.com ]

Name	Size	Permission
_bluetoothctl	2.35 KB	-rw-r--r--
_bootctl	2.84 KB	-rw-r--r--
_busctl	9.36 KB	-rw-r--r--
_bwrap	6.18 KB	-rw-r--r--
_coredumpctl	1.89 KB	-rw-r--r--
_curl	14.58 KB	-rw-r--r--
_firewalld	20.25 KB	-rw-r--r--
_flatpak	643 B	-rw-r--r--
_hostnamectl	2.73 KB	-rw-r--r--
_imunify360_agent	15.02 KB	-rw-r--r--
_journalctl	7.03 KB	-rw-r--r--
_kernel-install	779 B	-rw-r--r--
_localectl	3.68 KB	-rw-r--r--
_loginctl	6.25 KB	-rw-r--r--
_nvme	106.81 KB	-rw-r--r--
_p11-kit	981 B	-rw-r--r--
_sd_hosts_or_user_at_host	128 B	-rw-r--r--
_sd_machines	505 B	-rw-r--r--
_sd_outputmodes	318 B	-rw-r--r--
_sd_unit_files	263 B	-rw-r--r--
_systemctl	19.5 KB	-rw-r--r--
_systemd	3.76 KB	-rw-r--r--
_systemd-analyze	5.5 KB	-rw-r--r--
_systemd-delta	633 B	-rw-r--r--
_systemd-inhibit	1.15 KB	-rw-r--r--
_systemd-path	330 B	-rw-r--r--
_systemd-run	4.25 KB	-rw-r--r--
_systemd-tmpfiles	744 B	-rw-r--r--
_timedatectl	2 KB	-rw-r--r--
_trust	3 KB	-rw-r--r--
_udevadm	8.06 KB	-rw-r--r--
_wpctl	1.57 KB	-rw-r--r--

Code Editor : _trust

#compdef trust

local context state state_descr line
local -A opt_args
local -a reply

local -a optcommon=(
    '(-h --help)'{-h,--help}'[show a help message and exit]'
    '(-v --verbose)'{-v,--verbose}'[show verbose debug output]'
    '(-q --quiet)'{-q,--quiet}'[suppress command output]'
)

_trust_pkcs11() {
  local pkcs11_full="$(_call_program pkcs11 trust list)"
  local -a pkcs11=(${${${(M)${(@f)pkcs11_full}:#pkcs*}%;*}//:/\\:})
  local -a pkcs11_label=(
    ${${${(M)${(@f)pkcs11_full}:#[[:space:]]#label:*}#[[:space:]]#label: }//:/\\:}
  )

_describe -t pkcs11 'pkcs11 uri' pkcs11_label pkcs11 "$@"
}

_trust_extract_filter() {
  _alternative \
    'filter:filter:(ca-anchors blocklist trust-policy certificates)' \
    'pkcs11:pkcs11 uri:_trust_pkcs11'
}

_trust_dump_filter() {
  _alternative \
    'filter:filter:(all)' \
    'pkcs11:pkcs11 uri:_trust_pkcs11'
}

_trust_anchor() {
  _alternative \
    'files:file:_files' \
    'pkcs11:pkcs11 uri:_trust_pkcs11'
}

local -a trust_commands=(
  'list:list trust or certificates'
  'extract:extract certificates and trust'
  'extract-compat:extract trust compatibility bundles'
  'anchor:add, remove, or change trust anchors'
  'dump:dump trust objects in internal format'
  'check-format:check the format of .p11-kit files'
)

local -a formats=(
  x509-file x509-directory
  pem-bundle pem-directory pem-directory-hash
  openssl-bundle openssl-directory
  java-cacerts edk2-cacerts
)

_arguments -S \
  '(-h --help)'{-h,--help}'[show a help message a exit]' \
  '1:trust command:->command' \
  '*:: :->argument'

local ret=1
case $state-$line[1] in
  command-*)
    _describe -t trust-command 'trust command' trust_commands && ret=0
    ;;
  argument-list)
    _arguments -S $optcommon \
      '--filter=[filter of what to export]:filter:_trust_extract_filter' \
      '--purpose=[limit to certificates usable for the purpose]:purpose:(server-auth client-auth email code-signing)' \
      && ret=0
    ;;
  argument-extract)
    _arguments -S $optcommon \
      '--filter=[filter of what to export]:filter:_trust_extract_filter' \
      '--format=[format to extract to]:format:'"($formats)" \
      '--purpose=[limit to certificates usable for the purpose]:purpose:(server-auth client-auth email code-signing)' \
      '(-f --overwrite)'{-f,--overwrite}'[overwrite output file or directory]' \
      '--comment[add comments to bundles if possible]' \
      '1:destination:_files' && ret=0
    ;;
  argument-extract-compat)
    _arguments -S $optcommon \
      '(-o --output)'{-o+,--output=}'[write the extracted trust store to directory instead of updating /etc/ca-certificates/extracted]' \
      && ret=0
    ;;
  argument-anchor)
    _arguments -S $optcommon \
      + '(action)' \
        '--store: :_files' \
        '--remove: :_trust_anchor' && ret=0
    ;;
  argument-dump)
    _arguments -S $optcommon \
      '--filter=[filter what to export]:filter:_trust_dump_filter' && ret=0
    ;;
  argument-check-format)
    _arguments -S $optcommon \
      '1:file:_files' && ret=0
    ;;
esac
return ret

${this.title}

Code Editor : _trust